Public Sub GetTestRepository()

' Operations on the test repository
    

    Dim TestFact As TestFactory
    Dim ExtStor As IExtendedStorage
    Dim DownLoadPath As String
    Dim FilePath As String
'------------------------------------
' Get an IExtendedStorage object using
' TestFactory.RepositoryStorage
' and examine the local download path.
    'tdc is the global TDConnection object.
    Set TestFact = tdc.TestFactory
    Set ExtStor = TestFact.RepositoryStorage
With ExtStor
    Debug.Print .ClientPath
' The output is similar to the output below
' except that the string "423af35f"
' will be different on your client.
' C:\DOCUME~1\<user name>\LOCALS~1\Temp\TD_80\423af35f\Test
'
'------------------------------------
' Clean old files with IExtendedStorage.Delete
'   by recursively
'   deleting the entire local copy of
'   the repository.
' The "Test" directory and everything under
' it are deleted.
    .Delete "-r", TDOLE_DELETE_LOCAL
'
'------------------------------------
' Use IExtendedStorage.Load
' to refresh the local copy with all new files.
    DownLoadPath = .Load("*", True)
' Note that the download path is the IExtendedStorage
'   object's Client Path:
    Debug.Print "The download path: " & DownLoadPath
'The download path: _
C:\DOCUME~1\<user name>\LOCALS~1\Temp\TD_80\423af35f\Test
    Debug.Print "The Extended Storage Client Path: " & .ClientPath
'The Extended Storage Client Path: _
C:\DOCUME~1\<user name>\LOCALS~1\Temp\TD_80\423af35f\Test
'
'------------------------------------
' Use IExtendedStorage.Delete
'------------------------------------
' Delete a specific file.
'   The file path for deletion starts at
'   the extended storage root, so the
' full file path to this file is:
'   DownLoadPath + \trip_typ\script.vbs
    FilePath = "trip_typ\script.vbs"
    .Delete FilePath, TDOLE_DELETE_LOCAL
'
'------------------------------------
' Delete all files named batch.bat anywhere
' in the local copy of the repository.
    .Delete "-r batch.bat", TDOLE_DELETE_LOCAL
    
End With 'extstor
End Sub