Quit Method
Closes UFT One.
Visual Basic
Public Sub Quit() 
This method is parallel to choosing File > Exit in UFT One.

If UFT One is running in minimized mode (Application.Visible=False) and the currently open test or component contains unsaved changes, the Quit() statement fails and returns an error.

If UFT One is running in visible mode (Application.Visible=True) and the currently open test or component contains unsaved changes, a UFT One message box opens and prompts you to save the changes.

After using the Quit method to close UFT One , you can use the Launch method to start UFT One again. You do not need to recreate the Application object.

'This example opens a test and loads all the add-ins associated with the test.
'There is no unsaved test currently open in UFT One.
'For more information, see the example for the Test.SaveAs method.

Dim qtApp 'As QuickTest.Application ' Declare the Application object variable
Dim blnNeedChangeAddins ' Declare a flag for indicating whether the test's associated add-ins are currently loaded
Dim arrTestAddins ' Declare the variable for storing the test's associated add-ins

Set qtApp = CreateObject("QuickTest.Application") ' Create the Application object

arrTestAddins = qtApp.GetAssociatedAddinsForTest("C:\Tests\Test1") ' Create an array containing the list of addins associated with this test

' Check if all required add-ins are all already loaded
blnNeedChangeAddins = False ' Assume no change is necessary
For Each testAddin In arrTestAddins ' Iterate over the test's associated add-ins list
    If qtApp.Addins(testAddin).Status <> "Active" Then ' If an associated add-in is not loaded
        blnNeedChangeAddins = True ' Indicate that a change in the loaded add-ins is necessary
        Exit For ' Exit the loop
    End If

If qtApp.Launched And blnNeedChangeAddins Then
        qtApp.Quit ' If a change is necessary, exit UFT One to modify the loaded add-ins
End If

If blnNeedChangeAddins Then
    Dim blnActivateOK
    blnActivateOK = qtApp.SetActiveAddins(arrTestAddins, errorDescription) ' Load the add-ins associated with the test and check whether they load successfully.
    If Not blnActivateOK Then ' If a problem occurs while loading the add-ins
        MsgBox errorDescription ' Show a message containing the error
    WScript.Quit ' And end the automation program.
    End If
End If

If Not qtApp.Launched Then ' If UFT One is not yet open
    qtApp.Launch ' Start UFT One (with the correct add-ins loaded)
End If
qtApp.Visible = True ' Make the UFT One application visible

qtApp.Open "C:\Tests\Test1" ' Open the test
Set qtApp = Nothing ' Release the Application object
See Also